Excel 2010和Excel 2007可以將Excel工作簿另存為PDF格式文件，但手工的方法每次只能轉換一個工作簿，要轉換多個工作簿就顯得有些繁瑣。如果沒有批量轉換軟件，在Excel 2010和Excel 2007中，利用VBA代碼也可以輕松實現將Excel工作簿批量轉換為PDF，方法如下：

1.按Alt+F11，打開VBA編輯器。

2.在右側代碼窗口中輸入下列代碼：

Sub BatchConvertWorkBookToPDF()
Application.DisplayAlerts = False
Application.ScreenUpdating = False

Dim fDialog As FileDialog
Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
Dim vrtSelectedItem As Variant
Dim wkBook As Workbook
Dim showFolder As Boolean
showFolder = False
With fDialog
.Filters.Add "Excel文件", "*.xls; *.xlsx; *.xlsm", 1
If .Show = -1 Then
For Each vrtSelectedItem In .SelectedItems
'如果選擇了本工作簿則跳過
If InStrRev(vrtSelectedItem, ThisWorkbook.Name) = 0 Then
On Error Resume Next
Set wkBook = Application.Workbooks.Open(vrtSelectedItem, ReadOnly:=True, Password:="")
'跳過設置打開密碼的工作簿
If Not wkBook Is Nothing Then
'跳過隱藏的工作簿
If Windows(wkBook.Name).Visible = True Then
showFolder = True
'轉換開始
wkBook.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
Left(vrtSelectedItem, InStrRev(vrtSelectedItem, ".") - 1) & ".pdf" _
, Quality:=xlQualityMinimum, IncludeDocProperties:=False, IgnorePrintAreas _
:=True, OpenAfterPublish:=False
wkBook.Close , savechanges = False
Else
wkBook.Close , savechanges = False
End If
End If
End If
Next vrtSelectedItem
If showFolder Then Call Shell("explorer.exe " & Left(fDialog.SelectedItems(1), _
InStrRev(fDialog.SelectedItems(1), "\")), vbMaximizedFocus)
End If
End With

Set fDialog = Nothing
Application.ScreenUpdating = True
Application.DisplayAlerts = True
End Sub

3.將需要轉換的Excel工作簿復制到某個文件夾中。

4.關閉VBA編輯器返回Excel界面。按Alt+F8打開“宏”對話框，執行“BatchConvertWorkBookToPDF”宏。

5.在彈出的“瀏覽”對話框中選擇包含要轉換工作簿的文件夾，選擇所有要轉換的工作簿，單擊“打開”按鈕即可開始轉換。

說明：

1.已轉換的PDF文件位于原工作簿所在的文件夾中，轉換完成后會自動打開該文件夾。

2.不能轉換設置了打開密碼的工作簿、隱藏的工作簿、隱藏的工作表和包含上述VBA代碼的工作簿。

3.轉換的文件類型為“*.xls”、“*.xlsx”、“*.xlsm”。如果要轉換其他類型的工作簿，可在代碼中添加文件類型。

4.如果要轉換的工作簿具有相同的名稱和不同的后綴，如“Book1.xls”和“Book1.xlsx”，則先轉換的PDF文件會被覆蓋。

5.Excel2007必需安裝用于 2007 Microsoft Office system 的“另存為 PDF 或 XPS”加載項（見本站《如何將Excel工作簿保存為PDF格式文件》一文）。

單擊此處打開xlsm格式源文件下載頁面。